EOWEEK()

Returns the date of the last day of a week from Date or DateTime .

Sample usage

EOWEEK(TODAY())  returns the date of Saturday of this week from a Date . See also:  TODAY()

(EOWEEK(TODAY()) + 2)  returns the date of Monday of next week.

(EOWEEK(TODAY() + 7)) or (EOWEEK(TODAY()) + 7) returns the date of Saturday of next week.

(EOWEEK(TODAY()) - 7) returns the date of Saturday of last week. Equivalent to (TODAY() - WEEKDAY(TODAY())) . See also:  WEEKDAY()

EOWEEK(NOW()) returns the date of Saturday of this week from a DateTime . See also:  NOW()

EOWEEK("3/15/2020 14:00:00") returns  3/21/2020 (from a DateTime ).

EOWEEK("2/1/2020")  returns  2/1/2020 (from a Date ).

Week number

Computes the number of a week within its month.

 SWITCH(
  EOWEEK([date]),
  EOWEEK(EOMONTH([date], -1) + 1),
    1,
  EOWEEK(EOMONTH([date], -1) + 1 + 7),
    2,
  EOWEEK(EOMONTH([date], -1) + 1 + 14),
    3,
  EOWEEK(EOMONTH([date], -1) + 1 + 21),
    4,
  5
) 

Syntax

EOWEEK( when )

• when  - A  Date or DateTime value .

Note

Some constant values, such as "MM/DD/YYYY" , are evaluated as a Date value by AppSheet. Similarly, "000:00:00" is evaluated as a Duration value. This doesn't mean your spreadsheet data must use the same formats: the date and time formats in your spreadsheets are determined by the locale/language setting. Column will always be evaluated as the type of column. Additionally, you can convert data, both columns and string literals, to specific types using functions such as DATE() , TIME() , or DATETIME() . 

See also

Date and time expressions

DAY()

EOMONTH()

EWOMONTH()

MONTH()

WORKDAY()